Why do some piezoresistive analysis predict zero differential voltage?


In ANSYS 9.0, the piezoresistive elements solve for the total voltage, not the differential voltage due to applied stress. Therefore, if the applied stress is low, the round-off error can be of the same order of magnitude as the calculated voltage differences. In addition, ESYS (which is usually necessary to align the material axes with the applied stress) also increases the round-off error. This effect is especially evident in MEMS devices with voltage differences as small as several microvolts.

A 3D version of VM238 demonstrates this behavior. If the applied pressure (and thus the applied stress) is 1 MPa and the SPARSE MATRIX solver is used, the calculated differential pressure across the Wheatstone bridge is 0 volts. If the applied pressure is 1 MPa and the PCG solver is used, the calculated differential pressure is 3.45 microvolt. This difference is due to round-off error. If the applied pressure is increased to 10 MPa, the SPARSE and PCG solvers both calculate a differential voltage of 34.52 microvolt.

Caution should be exercised when using the piezoresistive elements to predict small differential voltages.

************************************************************
! 3D version of VM238
L = 180 ! length of the beam, um
W = 120 ! width of the beam, um
a = 100 ! length of piezoresistors, um
b = 20 ! width of piezoresistors, um
d = 10 ! distance from the edge, um
E = 165e3 ! modulus
nu = 0.25 ! poisson's ratio
rho = 7.8e-8 ! resistivity
p = 10 ! pressure
Vs = 5 ! voltage
ep = 3
/COM,
/COM, Piezoresistive coefficients (p-type Si), (MPa)^1
/COM, [p11 p12 p12 0 ]
/COM, [p12 p11 p12 0 ]
/COM, [p12 p12 p11 0 ]
/COM, [ 0 0 0 p44]
/COM,
p11 = 6.5E-5
p12 = -1.1E-5
p44 = 138.1E-5
/PREP7
ET,1,226,101
ET,2,95
LOCAL,11
LOCAL,12,,,,,45
MP,EX,1,E
MP,NUXY,1,nu
MP,RSVX,1,rho
TB,PZRS,1
TBDATA,1,p11,p12,p12
TBDATA,7,p12,p11,p12
TBDATA,13,p12,p12,p11
TBDATA,22,p44
tbdata,29,p44
tbdata,36,p44
CSYS,11
bloc,-L/2,L/2,-W/2,W/2,0,ep ! beam
bloc,-(L/2-d),-(L/2-d-b),-a/2,a/2,0,ep ! Resistor 1
bloc,-a/2,a/2,W/2-d-b,W/2-d,0,ep ! Resistor 2
bloc,-a/2,a/2,-(W/2-d),-(W/2-d-b),0,ep ! Resistor 3
bloc,L/2-d-b,L/2-d,-a/2,a/2,0,ep ! Resistor 4
VOVLAP,ALL
ESYS,12
et,3,200,7
vsel,s,volu,,2,5
alls,below,volu
type,3
ESIZE,b/3
amesh,7,25,6
type,1
esize,ep/2
vsweep,all
aclear,7,25,6
vsel,s,volu,,6
alls,below,volu
type,3
esize,b/3
amesh,31
TYPE,2
esize,ep/2
vsweep,6
aclear,31
ASEL,S,,,10
asel,a,,,17
NSLa,S,1
CP,1,VOLT,ALL
*GET,ns,NODE,0,NUM,MIN
D,NS,VOLT,Vs
asel,s,,,24
asel,a,,,27
NSLa,S,1
CP,2,VOLT,ALL
*GET,ng,NODE,0,NUM,MIN
D,NG,VOLT,0
asel,s,,,18
asel,a,,,28
NSLa,S,1
CP,3,VOLT,ALL
*GET,no1,NODE,0,NUM,MIN
asel,s,,,9
asel,a,,,23
NSLa,S,1
CP,4,VOLT,ALL
*GET,no2,NODE,0,NUM,MIN
NSEL,ALL
LSEL,ALL
NSEL,S,LOC,X,-L/2
D,ALL,UX,0
NSEL,R,LOC,Y,-W/2
D,ALL,UY,0
NSEL,S,LOC,X,L/2
SF,ALL,PRES,-p
NSEL,ALL
alls
/SOLU
ANTYPE,STATIC
eqslv,pcg,1e-8
SOLVE
/POST1
Sx = p
VOC = p44/(2+(p11+p12)*Sx)*Sx*Vs*1.e3 ! Target Result
VOA = abs(volt(no1)-volt(no2))*1.e3 ! ANSYS Result
*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,2
LABEL(1) = 'VO (mV)'
*VFILL,VALUE(1,1),DATA,VOC
*VFILL,VALUE(1,2),DATA,VOA
/COM
/COM,----- VM238 RESULTS COMPARISON --------
/COM,
/COM, | TARGET | ANSYS
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2)
(1X,A8,' ',F7.4,' ',F7.4)
/COM,---------------------------------------
fini
/exit





Show Form
No comments yet. Be the first to add a comment!