Do you have an example of piezoelectric [c] matrix input for a 2d case? I am having really hard time converting [c] matrix from 3D to 2D case.


Here is an ANSYS 11.0 input file from the test set that may clarify the input.

/title, Thermal strain in a 2-D piezoelectric analysis
/com, -- Target: piezoelectric analysis using plane13
/com,
/com, - compliance coefficients, m2/N
s11=16.4e-12
s12=-5.74e-12
s13=-7.22e-12
s33=18.8e-12
s44=47.5e-12
s66=44.3e-12
/com, - piezoelectric strain coefficients, C/N
d15=5.84e-10
d31=-1.71e-10
d33=3.74e-10
/com, - relative permittivity at constant stress
ep11=1730
ep33=1700
/com, - thermal expansion coefficient, 1/C
alphx=1.e-5
alphy=2.e-5
alphz=alphx

/nopr
/prep7
/com, -- Material matrices (polar axis along Y-axis): ANSYS input
/com,
/com, [s11 s13 s12 0 0 0 ] [ 0 d31 0 ] [ep11 0 0 ]
/com, [s13 s33 s13 0 0 0 ] [ 0 d33 0 ] [ 0 ep33 0 ]
/com, [s12 s13 s11 0 0 0 ] [ 0 d31 0 ] [ 0 0 ep11]
/com, [ 0 0 0 s44 0 0 ] [d15 0 0 ]
/com, [ 0 0 0 0 s44 0 ] [ 0 0 d15]
/com, [ 0 0 0 0 0 s66] [ 0 0 0 ]

tb,ANEL,1,,,1 ! anisotropic elastic compliance matrix
tbda,1,s11,s13,s12
tbda,7,s33,s13
tbda,12,s11
tbda,16,s44

tb,PIEZ,1,,,1 ! piezoelectric strain matrix
tbda,2,d31
tbda,5,d33
tbda,8,d31
tbda,10,d15

tb,DPER,1,,,1 ! dielectric permittivity at constant stress
tbda,1,ep11,ep33

mp,alpx,1,alphx
mp,alpy,1,alphy
mp,alpz,1,alphz

et,1,223,1001 ! plane stress
et,2,223,1001,,2 ! plane strain

esize,,1
rect,,1,,1
type,1
amesh,1

rect,,1,,1
type,2
amesh,2

nsel,s,loc,x,0
d,all,ux,0
nsel,r,loc,y,0
d,all,uy,0
nsel,s,loc,y,0
d,all,volt,0
nsel,all

tunif,-110
fini





Show Form
No comments yet. Be the first to add a comment!